Category: Uncategorized

Philips Hue bulb on sale

I have been dabbling with some home automation recently. I believe it makes more sense to control the light switches directly, rather than the individual bulbs. However, I have yet to find a system that has the longevity and availability in Europe that I expect from something that I would pay hundreds of Euros for.

Until I find that system I have put in a few Philips Hue White bulbs in strategic spots in the house. It is very cool when you pull up to the driveway and tell Siri to turn on the front light… Or dim the hallway lights when you are carrying stuff.

The prices for individual bulbs have dropped on Amazon yesterday. This may mean that an upgrade is imminent, but since the current bulbs work fine and work well with HomeKit  and Siri in iOS 9 and 10. This is a good chance to stock up on some units:

The links are affiliate links. When you buy I will get a small kickback… Thank you!

Copy all Safari tabs to Notes.app

I had previously posted about one of my oldest but still frequently used scripts which gathers all tabs from a window into a text list to be pasted in an email or something like that.

I have recently adapted that script to do something new. This new script will gather the tabs in the frontmost Safari window and create a note in the Notes app with all the links (then, presumably, you would want to clean out and close most of the tabs)

property defaultAccountName : "iCloud"
property defaultFolderName : "Saved Safari Windows"
global html
global processedURLs
on appendLineWithDoc(theDoc)
tell application "Safari"
tell theDoc
try
my appendHTML(" <li>")
my appendHTML("<a href=\"" & URL & "\">")
my appendHTML(name)
my appendHTML("</a></li>" & return)
set processedURLs to processedURLs & (URL as string)
end try
end tell
end tell
end appendLineWithDoc
on appendHTML(htmlString)
set html to html & htmlString
end appendHTML
on defaultFolder()
tell application "Notes"
if not (exists account defaultAccountName) then
display dialog "Cound not find account '" & defaultAccountName & "'!"
tell me to quit
end if
if exists folder defaultFolderName of account defaultAccountName then
return folder defaultFolderName of account defaultAccountName
end if
make new folder at account defaultAccountName with properties {name:defaultFolderName}
end tell
end defaultFolder
on run
set datestamp to "Saved on " & (short date string) of (current date) & " at " & (time string) of (current date) & return
set html to "<h1>" & datestamp & "</h1>" & return
my appendHTML("<ul>" & return)
set processedURLs to {}
tell application "Safari"
activate
set w to window 1
set n to 0
try -- this will fail for the downloads window
set n to count tabs of w
end try
if n > 1 then
repeat with t in every tab of w
my appendLineWithDoc(t)
end repeat
else if n = 1 then
my appendLineWithDoc(document of w)
end if
end tell
my appendHTML("</ul>" & return)
if (count of processedURLs) > 0 then
set f to my defaultFolder()
tell application "Notes"
make new note at f with properties {body:html, name:datestamp}
activate
end tell
end if
end run
view raw Save Tabs to Notes.applescript hosted with ❤ by GitHub

Also I learned that the Safari tabs from all your Macs and iOS devices are stored in the `~/Library/SyncedPreferences/com.apple.Safari.plist` and extended the script to read that instead of grabbing them directly from Safari:

property defaultAccountName : "iCloud"
property defaultFolderName : "Saved iCloud Tabs"
global html
global processedURLs
on appendLineWithURLItem(urlItem)
my appendHTML(" <li>")
my appendHTML("<a href=\"" & |url| of urlItem & "\">")
my appendHTML(|Title| of urlItem)
my appendHTML("</a></li>" & return)
set processedURLs to processedURLs & (|url| of urlItem)
end appendLineWithURLItem
on appendHTML(htmlString)
set html to html & htmlString
end appendHTML
on defaultFolder()
tell application "Notes"
if not (exists account defaultAccountName) then
display dialog "Cound not find account '" & defaultAccountName & "'!"
tell me to quit
end if
if exists folder defaultFolderName of account defaultAccountName then
return folder defaultFolderName of account defaultAccountName
end if
make new folder at account defaultAccountName with properties {name:defaultFolderName}
end tell
end defaultFolder
on run
set datestamp to "Saved on " & (short date string) of (current date) & " at " & (time string) of (current date) & return
set html to "<h1>" & datestamp & "</h1>" & return
set processedURLs to {}
tell application "System Events"
set SafariPrefsPlist to property list file "~/Library/SyncedPreferences/com.apple.Safari.plist"
repeat with x in every property list item of property list item "values" of SafariPrefsPlist
set v to property list item "value" of x
if exists property list item "Tabs" of v then
set deviceName to value of property list item "DeviceName" of v
my appendHTML("<h3>" & deviceName & "</h3>" & return)
my appendHTML("<ul>" & return)
set tabsPlist to value of property list item "Tabs" of v
repeat with i in tabsPlist
my appendLineWithURLItem(i)
end repeat
end if
my appendHTML("</ul>" & return)
end repeat
end tell
if (count of processedURLs) > 0 then
set f to my defaultFolder()
tell application "Notes"
make new note at f with properties {body:html, name:datestamp}
activate
end tell
end if
end run
view raw Save iCloud Tabs to Notes.applescript hosted with ❤ by GitHub

To use it is probably easiest to enable the Script menu (in Script Editor > Preferences) and drop the scripts in the `~/Library/Scripts/Applications/Safari` folder.

Using ShellCheck with BBEdit

Several people I follow in Twitter have pointed a quite useful looking tools called ShellCheck. It will scan shell script code for common problems that may lead to errors later, especially quoting.

However, the script is written in Haskell, which brings with it a rat’s tail of dependencies if you want to install it on your own Mac.

Since I did not want to bother with that I wrote a script that will grab the code from the frontmost BBEdit window and paste it into the webpage:

tell application "BBEdit"
if not (exists text document 1) then
return
end if
if source language of text document 1 is not "UNIX Shell Script" then
set thename to name of text document 1
display dialog "Document '" & thename & "' does not seem to be a shell script!"
return
end if
set theCode to text of text document 1
end tell
-- escape some crticial characters
set theCode to replace_chars(theCode, "\\", "\\\\")
set theCode to replace_chars(theCode, quote, "\"")
set theCode to replace_chars(theCode, "'", "\\'")
set theCode to replace_chars(theCode, "\n", "\\n")
tell application "Safari"
open location "http://shellcheck.net"
delay 1
do JavaScript "document.getElementById('code').value = '" & theCode & "';" in document 1
do JavaScript "transfer('#code', '#console')" in document 1
end tell
-- from the ever useful http://macosxautomation.com/applescript/sbrt/sbrt-06.html
on replace_chars(this_text, search_string, replacement_string)
set AppleScript's text item delimiters to the search_string
set the item_list to every text item of this_text
set AppleScript's text item delimiters to the replacement_string
set this_text to the item_list as string
set AppleScript's text item delimiters to ""
return this_text
end replace_chars
view raw shellcheck hosted with ❤ by GitHub

Drop this in your BBEdit Scripts folder and enjoy!

Connect to Active Directory with a Profile


In OS X 10.9 Mavericks Apple added the option to connect a Mac client to Active Directory with a configuration profile. In previous OS versions admins have to script AD connection with the dsconfigad CLI tool.


Many of the configuration options for this profile are described here. By default the client Mac’s hostname will be used as the machine record name to connect to AD. However, you can provide a ClientID key to override the default. There are also placeholders you can provide for this filed as described here. In our setup we use the ComputerName (as defined in Sharing preference pane or with scutil --set ComputerName) instead, since the hostname of a given MacBook may change depending on which Thunderbolt ethernet adaptor is used.


The easiest way to create an Active Directory Profile is to use Profile Manager on OS X Server to create one with the settings you want, then download the profile and further edit in a text editor. You can also use this generic Active Directory configuration profile as a starting point.